primary_censored_dist_analytical_cdf.stan

Go to the documentation of this file.

 
int check_for_analytical(int dist_id, int primary_dist_id) {
  if (dist_id == 2 && primary_dist_id == 1) return 1; // Gamma delay with Uniform primary
  if (dist_id == 1 && primary_dist_id == 1) return 1; // Lognormal delay with Uniform primary
  return 0; // No analytical solution for other combinations
}
 
real primary_censored_gamma_uniform_lcdf(data real d, real q, array[] real params, data real pwindow) {
  real shape = params[1];
  real rate = params[2];
  real shape_1 = shape + 1;
  real log_window = log(pwindow);
 
  real log_F_T = gamma_lcdf(d | shape, rate);
  real log_F_T_kp1 = gamma_lcdf(d | shape_1, rate);
 
  real log_delta_F_T_kp1;
  real log_delta_F_T_k;
  real log_F_Splus;
 
  if (q != 0) {
    real log_F_T_q = gamma_lcdf(q | shape, rate);
    real log_F_T_q_kp1 = gamma_lcdf(q | shape_1, rate);
 
    // Ensure that the first argument is greater than the second
    log_delta_F_T_kp1 = log_diff_exp(log_F_T_kp1, log_F_T_q_kp1);
    log_delta_F_T_k = log_diff_exp(log_F_T, log_F_T_q);
 
    log_F_Splus = log_diff_exp(
      log_F_T,
      log_diff_exp(
        log(shape * inv(rate)) + log_delta_F_T_kp1,
        log(d - pwindow) + log_delta_F_T_k
      ) - log_window
    );
  } else {
    log_delta_F_T_kp1 = log_F_T_kp1;
    log_delta_F_T_k = log_F_T;
 
    log_F_Splus = log_diff_exp(
      log_F_T,
      log_sum_exp(
        log(shape * inv(rate)) + log_delta_F_T_kp1,
        log(pwindow - d) + log_delta_F_T_k
      ) - log_window
    );
  }
 
  return log_F_Splus;
}
 
real primary_censored_lognormal_uniform_lcdf(data real d, real q, array[] real params, data real pwindow) {
  real mu = params[1];
  real sigma = params[2];
  real mu_sigma2 = mu + square(sigma);
  real log_window = log(pwindow);
 
  real log_F_T = lognormal_lcdf(d | mu, sigma);
  real log_F_T_mu_sigma2 = lognormal_lcdf(d | mu_sigma2, sigma);
 
  real log_delta_F_T_mu_sigma;
  real log_delta_F_T;
  real log_F_Splus;
 
  if (q != 0) {
    real log_F_T_q = lognormal_lcdf(q | mu, sigma);
    real log_F_T_q_mu_sigma2 = lognormal_lcdf(q | mu_sigma2, sigma);
 
    // Ensure that the first argument is greater than the second
    log_delta_F_T_mu_sigma = log_diff_exp(
      log_F_T_mu_sigma2, log_F_T_q_mu_sigma2
    );
    log_delta_F_T = log_diff_exp(log_F_T, log_F_T_q);
 
    log_F_Splus = log_diff_exp(
      log_F_T,
      log_diff_exp(
        (mu + 0.5 * square(sigma)) + log_delta_F_T_mu_sigma,
        log(d - pwindow) + log_delta_F_T
      ) - log_window
    );
  } else {
    log_delta_F_T_mu_sigma = log_F_T_mu_sigma2;
    log_delta_F_T = log_F_T;
 
    log_F_Splus = log_diff_exp(
      log_F_T,
      log_sum_exp(
        (mu + 0.5 * square(sigma)) + log_delta_F_T_mu_sigma,
        log(pwindow - d) + log_delta_F_T
      ) - log_window
    );
  }
 
  return log_F_Splus;
}
 
real primary_censored_dist_analytical_lcdf(data real d, int dist_id,
                                           array[] real params,
                                           data real pwindow, data real D,
                                           int primary_dist_id,
                                           array[] real primary_params) {
  real result;
  real log_cdf_D;
 
  if (d <= 0) return negative_infinity();
  if (d >= D) return 0;
 
  real q = max({d - pwindow, 0});
 
  if (dist_id == 2 && primary_dist_id == 1) {
    // Gamma delay with Uniform primary
    result = primary_censored_gamma_uniform_lcdf(d | q, params, pwindow);
  } else if (dist_id == 1 && primary_dist_id == 1) {
    // Lognormal delay with Uniform primary
    result = primary_censored_lognormal_uniform_lcdf(d | q, params, pwindow);
  } else {
    // No analytical solution available
    return negative_infinity();
  }
 
  if (!is_inf(D)) {
    log_cdf_D = primary_censored_dist_lcdf(
      D | dist_id, params, pwindow, positive_infinity(),
      primary_dist_id, primary_params
    );
    result = result - log_cdf_D;
  }
 
  return result;
}
 
real primary_censored_dist_analytical_cdf(data real d, int dist_id,
                                          array[] real params,
                                          data real pwindow, data real D,
                                          int primary_dist_id,
                                          array[] real primary_params) {
  return exp(primary_censored_dist_analytical_lcdf(d | dist_id, params, pwindow, D, primary_dist_id, primary_params));
}